*
* ..File: xdPij0.f  
*
*
* ..The LO splitting functions  DeltaP_ij^(0) for the evolution of 
*    polarized partons densities. Expansion parameter: alpha_s/(4 pi).
* 
* ..The distributions (in the mathematical sense) are given as in eq.
*    (B.26) of Floratos, Kounnas, Lacaze: Nucl. Phys. B192 (1981) 417.
*    The name-endings A, B, and C of the functions below correspond to 
*    the kernel superscripts [2], [3], and [1] in that equation.
*
*
* =====================================================================
*
*
* ..1-loop quark-quark splitting function  DeltaP_qq^(1), regular part.
*
       FUNCTION DP0QQA (X)
       IMPLICIT REAL*8 (A - Z)
*
       CF = 4./3.D0
       DP0QQA = - 2.*CF * (1.+ X)
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
* ..The singular (soft) piece of DeltaP_qq^(0)
*
       FUNCTION DP0QQB (X)
       IMPLICIT REAL*8 (A - Z)
*
       CF = 4./3.D0
       DP0QQB = 4.*CF / (1.D0-X)
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
* ..The 'local' piece of DeltaP_qq^(0)
*
       FUNCTION DP0QQC (X)
       IMPLICIT REAL*8 (A - Z)
*
       CF = 4./3.D0
       DP0QQC = 4.*CF * LOG (1.D0-X) + 3.*CF
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
*
* ..The 1-loop gluon->quark splitting function DeltaP_qg^(0)
*
       FUNCTION DP0QGA (X, NF)
       IMPLICIT REAL*8 (A - Z)
       INTEGER NF
*
       DP0QGA = nf * ( - 2.D0 + 4.D0*x )
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
*
* ..The 1-loop quark->gluon splitting function DeltaP_gq^(0)
*
       FUNCTION DP0GQA (X)
       IMPLICIT REAL*8 (A - Z)
*
       CF = 4./3.D0
       DP0GQA = cf * ( 4.D0 - 2.D0*x )
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
*
* ..1-loop gluon-gluon splitting function DeltaP_gg^(0), regular part
*
       FUNCTION DP0GGA (X)
       IMPLICIT REAL*8 (A - Z)
*
       CA = 3.D0
*
       DP0GGA = 4.*CA * (1.- 2.*X)
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
* ..The singular (soft) piece of DeltaP_gg^(0)
*
       FUNCTION DP0GGB (X)
       IMPLICIT REAL*8 (A - Z)
*
       CA = 3.D0
       DP0GGB = 4.*CA / (1.D0-X)
*
       RETURN
       END
*
* ---------------------------------------------------------------------
*
* ..The 'local' piece of DeltaP_gg^(0)
*
       FUNCTION DP0GGC (X, NF)
*
       IMPLICIT REAL*8 (A - Z)
       INTEGER NF
*
       CA = 3.D0
       DP0GGC = 4.*CA * LOG (1.D0-X) - 2./3.D0 * NF + 11./3.D0 * CA
*
       RETURN
       END
*
* =================================================================av==
